Examples

Below is the sample code that comes with the Falcon ZIP file of examples and instructions.

VARIABLES EXAMPLE (AS)

package falcon{
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.text.TextField;
	public class FalconVariables extends MovieClip {
		public function FalconVariables() {
			var myFalcon:Falcon=new Falcon("http://www.yoursite.com/yourscript.php");
			myFalcon.addEventListener(Event.COMPLETE,getData);
		}
		private function getData(e:Event) {
			if (e.target.error) {
				myText.text = "sorry, error connecting to server script";
			} else {
				myText.text = e.target.data.yourVariable; // will say Hello...
			}
		}
	}
}

VARIABLES EXAMPLE (PHP)

<?PHP
	echo "yourVariable=Hello from the server";
?>

TEXT EXAMPLE (AS)

package falcon{
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.text.TextField;
	public class FalconText extends MovieClip {
		public function FalconText() {
			var myFalcon:Falcon=new Falcon("sample.txt", Falcon.TEXT);
			myFalcon.addEventListener(Event.COMPLETE,getData);
		}
		private function getData(e:Event) {
			if (e.target.error) {
				myText.text = "sorry, error accessing text file";
			} else {
				myText.text = e.target.data;
			}
		}
	}
}

TEXT EXAMPLE (TXT)

Hello from a text file

How are you?

XML EXAMPLE (AS)

package falcon{
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.text.TextField;
	public class FalconXML extends MovieClip {
		public function FalconXML() {
			var myFalcon:Falcon=new Falcon("sample.xml", Falcon.XML_DATA);
			myFalcon.addEventListener(Event.COMPLETE,getData);
		}
		private function getData(e:Event) {
			if (e.target.error) {
				myText.text = "sorry, error connecting to XML file";
			} else {
				myText.text = e.target.data.text; 
				myText.appendText("\n\n"); // new lines
				myText.appendText(e.target.data.author);
				myText.appendText("\n"); 
				myText.appendText(e.target.data.location.@city);
				myText.appendText(", "); 
				myText.appendText(e.target.data.location.@country);
			}
		}
	}
}

XML EXAMPLE (XML)

<?xml version="1.0" encoding="utf-8"?>
<sample>
	<text><![CDATA[Hello there from <XML>]]></text>
	<author>Dan Zen</author>
	<location country="Canada" city="Dundas" />
</sample>

DATA PROVIDER EXAMPLE (AS)

package falcon{
	import flash.display.MovieClip;
	import flash.events.*;
	import flash.text.TextField;
	import flash.net.navigateToURL;
	import flash.net.URLRequest;
	import fl.data.DataProvider;
	public class FalconDataProvider extends MovieClip {
		// this code uses the FalconProvider class to send and load variables
		// FalconProvider is a class that wraps the half dozen Flash data classes
		// FalconProvider also creates a dataProvider for sequenced data (name1, name2, name3, etc.)
		private var myFalcon:FalconProvider;
		private var myScriptURL:String = "http://www.yourserver.com/yourscript.php";
		private var myDataType:String = FalconProvider.VARIABLES;
		private var mySendVars:Object = new Object; // object for sending variables
		public function FalconDataProvider() {
			getData();
			mySubmit.addEventListener(MouseEvent.CLICK, submitData);
		}
		function getData(myFirstName:String="", myLastName:String="", myFear:String="") {
			// preparing data to send to the server script
			mySendVars.firstName = myFirstName;
			mySendVars.lastName = myLastName;
			mySendVars.fear = myFear;

			// here we create a Falcon Object to send and receive data from the server script
			myFalcon = new FalconProvider(myScriptURL, myDataType, mySendVars);
			myFalcon.addEventListener(Event.COMPLETE, showGrid);
		}
		private function showGrid(e:Event) {
			if (e.target.error) {
				trace("there was an error connecting to the server");
			} else if (e.target.data.error != 0) {// (optional) we are sending a error check from the server script
				trace(e.target.data.error);
			} else {
				// if variables are sent with number iterators like:
				// name1, age1, name2, age2, etc. (or name0, age0, name1, age1, etc.)
				// then these are put in e.target.dataProvider as name, age, etc.
				// this allows you to populate DataGrid objects as below
				// or populate List and ComboBox objects using label1, data1, label2, data2, etc.
				myGrid.columns = ["firstName", "lastName", "fear"];
				myGrid.dataProvider = e.target.dataProvider;
				myGrid.getColumnAt(0).headerText = "First Name";
				myGrid.getColumnAt(0).width = 90;
				myGrid.getColumnAt(1).headerText = "Last Name";
				myGrid.getColumnAt(1).width = 90;
				myGrid.getColumnAt(2).headerText = "Greatest Fear";
			}
		}
		function submitData(e:MouseEvent) {
			if (firstName.text == "" || lastName.text == "" || fear.text == "") {
				navigateToURL(new URLRequest("javascript:alert('Please enter all fields');"), "_self");
			} else {
				getData(firstName.text, lastName.text, fear.text);
				firstName.text = lastName.text = fear.text = "";
			}
		}
	}
}

DATA PROVIDER EXAMPLE (PHP)

<?php
	$firstName = isset($_POST['firstName']) ? $_POST['firstName'] : "";
	$lastName = isset($_POST['lastName']) ? $_POST['lastName'] : "";
	$fear = isset($_POST['fear']) ? $_POST['fear'] : "";

	$date = date("Y-m-d");
	$error = 0;

	// PRE-MAKE DATABASE
	// go to phpmyadmin
	// login and make a table called "fears" with 5 fields
	// id - make it an INT and autoincrementing and the key
	// firstName - make TEXT
	// lastName - make TEXT
	// fear - make TEXT
	// date - male Date

	// OPEN DATABASE
	// use your username and password
	$db = mysql_connect("localhost", "yourUsername", "yourPassword");
	mysql_select_db("yourDatabase",$db);
	
	if ($firstName != "") {
		// INPUT TO MYSQL
		// create SQL query to insert any names and fears into the "fears" table
		$query = "INSERT INTO fears (id, firstName, lastName, fear, date) VALUES ('', '$firstName', '$lastName', '$fear', '$date')";
		// use PHP function to execute query.  We use this function every time we
		// want to access the database - for instance to add, delete or change something
		$result = mysql_query($query,$db);
		if (!$result) {
			$error = "Sorry could not record fear";
		}		
	}	
	
	// OUTPUT TO FLASH
	// this is how we handle sending variables back to Flash
	// note that all name=value pairs are separated by &
	$query = "SELECT * FROM fears";
	$result = mysql_query($query,$db);
	$total = mysql_num_rows($result);
	$output = "";
	if ($result) {
		$i=0;
		while ($myrow = mysql_fetch_array($result)) {
			$i++;
			$output .= "&firstName".$i."=".urlencode($myrow['firstName']).
				   "&lastName".$i."=".urlencode($myrow['lastName']).
				   "&fear".$i."=".urlencode($myrow['fear']);
		}
	} else {
		$error = "Sorry could not access fears";
	}

	// send the data to Flash using the URL encoded format
	echo "total=".urlencode($total)."&error=".urlencode($error).$output;
?>